source: trunk/npemap.org.uk/cgi/get-postcodes.fcgi @ 512

#!/usr/bin/perl
#
# Copyright (c) 2006 Dominic Hargreaves
# See accompanying file "LICENCE" for licence details

use strict;
use warnings;

use CGI::Fast qw/:standard -debug/;

# Find our private perl libraries
use FindBin;
use lib "$FindBin::Bin/../perllib";
use NPEMap;

sub print_err;

# Set up database handler to try and make sure it's ready for the first
# request
# No point in handling errors here since they'll get handled by the request
# handler
my $dbh = setup_dbh();


my @fields = qw(mineasting minnorthing maxeasting maxnorthing);
my $max_distance = 50000; # in metres

my %grid_max = (
        easting  => { 'gb' => 700000, 'ie' => 400000 },
        northing => { 'gb' => 1300000, 'ie' => 500000 },
);

my $cgi;
# Process incoming requests
REQUEST: while ($cgi = new CGI::Fast) {

    # In case the database went away, make sure we have a connection
    unless ($dbh = setup_dbh()) {
        print_internal_err('Error setting up database connection');
        next REQUEST;
    }

        # Did they request the irish grid?
        my $grid = 'gb';
        my $ie = 0;
        if(defined $cgi->param('ie')) {
                $grid = 'ie';
                $ie = 1;
        }

    # Input validation
    foreach my $field (@fields) {
        unless (defined $cgi->param($field)) {
            print_err ("Parameter '$field' missing");
            next REQUEST;
        }
    }

    # Are the Eastings in a valid range?
    foreach (qw(mineasting maxeasting)) {
        if (($cgi->param($_) > $grid_max{'easting'}->{$grid}) or
            ($cgi->param($_) < 0)) {
            print_err ("Parameter '$_' must be an integer between 0 and ".($grid_max{'easting'}->{$grid}/1000).",000");
            next REQUEST;
        }
    }

    # Are the Northings in a valid range?
    foreach (qw(minnorthing maxnorthing)) {
        if (($cgi->param($_) > $grid_max{'northing'}->{$grid}) or
            ($cgi->param($_) < 0)) {
            print_err("Parameter '$_' must be an integer between 0 and ".($grid_max{'northing'}->{$grid}/1000).",000");
            next REQUEST;
        }
    }
    
    # Is the box too big?
    if (($cgi->param('maxeasting') - $cgi->param('mineasting') > $max_distance) or ($cgi->param('maxnorthing') - $cgi->param('minnorthing') > $max_distance)) {
        print_err("The requested box is too large");
        next REQUEST;
    }

        my ($e,$n) = ("easting","northing");
        if($ie) { ($e,$n) = ("ie_easting","ie_northing"); }
    my $sth = $dbh->prepare("SELECT outward || ' ' || inward AS postcode, $e, $n,id,source FROM postcodes WHERE $e BETWEEN ? AND ? AND $n BETWEEN ? AND ? AND NOT deleted");
    
    if ($sth->execute($cgi->param('mineasting'), $cgi->param('maxeasting'), $cgi->param('minnorthing'), $cgi->param('maxnorthing'))) {
        print "Content-type: text/javascript\n\n";

        while(my @row = $sth->fetchrow_array) {
                        my ($postcode,$easting,$northing,$id,$source) = @row;
            print "addMarker('$postcode', $easting, $northing, [$id, $source]);\n";
        }
        print "completeMarkers();\n";
    } else {
        print_internal_err("Database error retrieving data");
    }

}

# No more requests to serve, so tidy up
$dbh->disconnect;

# Helper routines
sub print_err {
    my $err = shift;
    print header("text/plain", "400 $err");
    print "Error: $err\n";
}

sub print_internal_err {
    my $err = shift;
    print header("text/plain", "500 $err");
    print "Error: $err\n";
}