source: trunk/npemap.org.uk/cgi/submit.fcgi @ 313

#!/usr/bin/perl
#
# Copyright (c) 2006 Dominic Hargreaves
# See accompanying file "LICENCE" for licence details

use strict;
use warnings;

use CGI::Fast qw/:standard -debug/;
use Geo::Postcode;

# Find our private perl libraries
use FindBin;
use lib "$FindBin::Bin/../perllib";
use NPEMap;
use NPEMap::Postcodes;

# Set up database handler to try and make sure it's ready for the first
# request
# No point in handling errors here since they'll get handled by the request
# handler
my $dbh = setup_dbh();

my @fields = qw(easting northing postcode1 postcode2);
my $returnBaseURL = '';

my $googleAnalytics = <<"HERE";
<script src="http://www.google-analytics.com/urchin.js" type="text/javascript">
</script>
<script type="text/javascript">
_uacct = "UA-732621-2";
if (typeof urchinTracker == 'function') urchinTracker();
</script>
HERE
my $cgi;
# Process incoming requests
REQUEST: while ($cgi = new CGI::Fast) {

my $returnlink = '';
    


    # In case the database went away, make sure we have a connection
    unless ($dbh = setup_dbh()) {
        print_html_err('Error setting up database connection', $returnlink);
        next REQUEST;
    }

    my ($easting, $northing);

    # Input validation
    foreach my $field (@fields) {
        unless (defined $cgi->param($field)) {
            print_html_err ("Parameter '$field' missing", $returnlink);
            next REQUEST;
        }
    }

    # Is the Easting in a valid range?
    if (($cgi->param('easting') > 700000) or
        ($cgi->param('easting') < 0)) {
        print_html_err ("Parameter 'easting' must be an integer between 0 and 700,000", $returnlink);
        next REQUEST;
    } else {
        $easting = $cgi->param('easting');
    }

    # Is the Northing in a valid range?
    if (($cgi->param('northing') > 1300000) or
        ($cgi->param('northing') < 0)) {
        print_html_err("Parameter 'northing' must be an integer between 0 and 1,300,000", $returnlink);
        next REQUEST;
    } else {
        $northing = $cgi->param('northing');
    }

    my $sth;

    # Now validate the postcode input format
    my ($trimmed_1, $trimmed_2) = ($cgi->param('postcode1'), $cgi->param('postcode2'));
    $trimmed_1 =~ s/^\s+//;
    $trimmed_2 =~ s/^\s+//;
    $trimmed_1 =~ s/\s+$//;
    $trimmed_2 =~ s/\s+$//;
    my $raw_postcode = $trimmed_1;
    $raw_postcode .= ' ' . $trimmed_2 if defined $trimmed_2;

    unless ((length($trimmed_2)) == 1 or (length($trimmed_2) == 0) or (length($trimmed_2) == 3) or (!defined $trimmed_2)) {
        print_html_err("The postcode format is not valid", $returnlink);
        next REQUEST;
    }

    my $postcode = Geo::Postcode->new($raw_postcode);
    my ($first, $second, $third, $fourth) = @{$postcode->fragments};
    my ($outward, $inward);

    if ($postcode->valid) {
        # We have a complete postcode; input it straight into the database
        $outward = $first . $second;
        $inward = $third . $fourth;
    } elsif($postcode->valid_fragment) {
        # We have a valid fragment; let's build up what we can
        # We are guaranteed to have the first two
        $outward = $first . $second;
        $inward = '';
        $inward .= $third if defined $third;
        $inward .= $fourth if defined $fourth;
    } else {
        print_html_err("The postcode format is not valid", $returnlink);
        next REQUEST;
    }

    # Check for a duplicate.
    # We want to collect duplicates from different IP addresses as a kind of
    # corroboration factor; this just catches accidental double-submission
    # really.
    $sth = $dbh->prepare('SELECT raw_postcode_outward FROM postcodes WHERE raw_postcode_outward = ? AND raw_postcode_inward = ? AND easting = ? AND northing = ? AND ip = ? AND NOT deleted');
    unless ($sth->execute($cgi->param('postcode1'), $cgi->param('postcode2'), $easting, $northing, $ENV{'REMOTE_ADDR'})) {
        print_html_err('Database error when checking for duplicate data :(', $returnlink);
        next REQUEST;
    }

    if ($sth->rows) {
        print_html_err('You, or someone with the same IP address, have already submitted this postcode with these co-ordinates.', $returnlink);
        next REQUEST;
    }

    $sth = $dbh->prepare('INSERT INTO postcodes (outward, inward, raw_postcode_outward, raw_postcode_inward, easting, northing, ip, source, user_agent) VALUES (?, ?, ?, ?, ?, ?, ?, 0, ?)');
    if ($sth->execute($outward, $inward, $cgi->param('postcode1'), $cgi->param('postcode2'), $easting, $northing, $ENV{'REMOTE_ADDR'}, $ENV{'HTTP_USER_AGENT'})) {
        print "Content-type: text/html\n\n";
        print "<p>Thank you for telling us where your post code is!</p>\n";
        # Any extra actions
        build_home_stats($dbh);
        next REQUEST;
    } else {
        print STDERR "DB error: " . $dbh->errstr . "\n";
        print_html_err("Database error when adding your data :(", $returnlink);
        next REQUEST;
    }

# WE NEVER GET HERE

}

# No more requests to serve, so tidy up
$dbh->disconnect;