source: trunk/npemap.org.uk/scripts/process-problems @ 320

#!/usr/bin/perl

use strict;
use warnings;

use FindBin;

# Find our private perl libraries
use lib "$FindBin::Bin/../perllib";
use NPEMap;

my $dbh = setup_dbh() or die $!;

my $sql = <<EOF;
SELECT   p.id, outward, inward, p.ip AS sub_ip, b.ip AS prob_ip, b.reason,
         reporter_email, p.created_at AS sub_date, b.created_at AS prob_date,
         p.easting, p.northing
FROM     bad_postcodes AS b INNER JOIN postcodes AS p ON (b.postcode = p.id)
WHERE    not b.actioned
ORDER BY p.id, b.created_at
EOF

my $sth = $dbh->prepare($sql);
$sth->execute or die $dbh->errstr;

if ($sth->rows == 0) {
    print "No problems\n";
    exit 0;
}

# Build up a list of allowed IDs to delete
my %probids;

my $hr;
while ($hr = $sth->fetchrow_hashref) {
    $probids{$hr->{'id'}}++;
    $hr->{'reporter_email'} = 'anon' unless $hr->{'reporter_email'};
    $hr->{'prob_ip'} = 'unknown IP' unless $hr->{'prob_ip'};
    $hr->{'sub_ip'} = '' unless $hr->{'sub_ip'};
    print $hr->{'id'} . ': ' . $hr->{'outward'} . ' ' . $hr->{'inward'} . ': ';
    print "by " . $hr->{'reporter_email'};
    print " at " . $hr->{'prob_ip'};
    print ' (SAME IP)' if ($hr->{'prob_ip'} eq $hr->{'sub_ip'});
    print "\n";
    print " ";
    print "Reason: " . $hr->{'reason'} . ' ' if $hr->{'reason'};
    print "(". $hr->{'prob_date'} . ")\n";
    print " http://www.npemap.org.uk/tiles/map.html#" .
        int($hr->{'easting'} / 1000) . ',' . int($hr->{'northing'} / 1000) . ",1\n";
}

my $del1sth = $dbh->prepare("UPDATE postcodes SET deleted = 't', delete_reason = 1 WHERE id = ?");
my $del2sth = $dbh->prepare("UPDATE bad_postcodes SET actioned = 't' WHERE postcode = ?");

# Now prompt for deletions
while (1) {
    unless (%probids) {
        print "No more problems.\n";
        last;
    }
    print "Resolve problem by deleting (^C to exit): ";
    my $input = <STDIN>;
    chomp $input;
    if ($probids{$input}) {
        $del1sth->execute($input) or warn $dbh->errstr;
        $del2sth->execute($input) or warn $dbh->errstr;
        delete $probids{$input};
    } else {
        print "$input is not a valid deletion candidate.\n";
    }
}

$dbh->disconnect;